"TREASURES OF AN UNSPECIFIED REGION OR DISTRICT" by "S. John Ross & Your Name Here"

[Paste the entire contents of source file into the Inform 7 IDE to get started]

[This is version 3.00 of this document. This document is entirely "unsupported," released for fun to see what (if anything) happens with it ... Honestly, I don't understand half this stuff, myself.]

[[[[[[[ -----------------> WTF? <----------------- ]]]]]]

Just in case any EC fan has an urge to write new adventures for the ToaSK barbarian (or another Encounter Critical hero or heroine), I've prepared this stripped-down adaptation of the game's Inform 7 source code. This doesn't include ToaSK itself, but it includes most of the basic fiddles ToaSK inflicts on Inform 7's standard behavior, including miniature versions of the random tables used for things like atmosphere, swearing by Huron, and Ranks. It also includes crunchy stuff like the modified status bar, the simplest version of the combat rules, and so forth. It also includes three simple locations, a weapon, a suit of armor, a scrap of paper, and a docile (but still dangerous) foe, to provide templates you can use to make your own adventure.

I say "adaptation" because ToaURoD, unlike ToaSK, is for the most current (as of this writing) version of Inform 7, while ToaSK itself is trapped in the amber of an earlier I7 release, for safey and sanity's sake. ToaUROD also began early enough in ToaSK's own lifetime that the two diverged a bit (on the inside). But that's a good and necessary thing, since I7 is a beautiful beast still a'borning. The approaches here are more compatible (though perhaps only a little) with where I7 is heading, and if I get around to doing the ToaSK sequels I'd like to do, ToaURoD is where I'll be starting from.

To make use of this thing, you'll need Inform 7 Build 6F95, using the following versions of the following extensions (several of which are bundled directly with Inform 7):

   Basic Screen Effects, by Emily Short
   Default Messages, by David Fisher
   Exit Lister, by Eric Eve
   Extended Banner, by Stephen Granade
   List Control, by Eric Eve
   Plurality, by Emily Short
   Punctuation Removal, by Emily Short
   Standard Rules, by Graham Nelson

Now, the PROBLEM with that is that, by the time you read this, the next release of Inform 7 is probably already out, and many of the extensions will likewise have later versions ... so you may have to do some serious fiddling, or dig into the archives to download the versions specified (the IF community, as near as I can tell, archives pretty much everything). This code MAY work with future versions, but probably will not, at least without a few fixes. If there's any evidence of interest I'll upate ToaURoD now and then to keep it fresh. 

There's a lot of potentially-confusing stuff here, but skip ahead to the "Volume of the Game World" and you'll find the easy-to-use parts. To make any sensible use of this (or, better still, ridiculous use of it) you'll need some working knowledge of Inform 7, but that's fun! I would recommend creating at least one small, working game in "vanilla" Inform 7 before tackling some of the oddness of the ToaSK version of things. This is, in some ways, a blatant abuse of the system.

In some cases, I've left in (but green-bracketed) bits of ToaSK code that have no business here, to provide examples and/or distracting clutter.

Some legal/licensing/permission-ish type stuff:

* INFORM 7 and EXTENSIONS: These all have their own notices and terms; see those.

* CODE: Do whatever you want with the code *around* the strings. I bequeath it to all those who truly enjoy inefficient, hackish, kludgy, functionally clueless Inform 7 programming written by a total non-programmer. Use it in good health, with no strings (ha!) attached, no need for credit, etc.

* STRINGS AND COMMENTARY: All strings and commentary in this document are Copyright (c) 2008,2009,2010 by S. John Ross, with all rights reserved. Permission is granted, however, to use 'em for non-commercial fanmade IF works imitating the style and tone of TREASURES OF A SLAVER'S KINGDOM and released in support of Encounter Critical. There are, beyond that, two special conditions ...

* TWO SPECIAL CONDITIONS: In any game making use of the strings here, the "story headline" string must never be altered, subverted, or contradicted, and it must always appear in the opening game-screen. Furthermore, the following unaltered string must appear as part of the responses to both the ABOUT and VERSION commands:

"Portions of this game appeared originally in [b]Treasures of a Slaver[']s Kingdom[n], copyright (c) 2007,2008,2009,2010 by S. John Ross, and appear here by permission. [quotation mark]Encounter Critical[quotation mark] and terms unique to it are trademarks of S. John Ross."

[[[[[[ ---------- AND THAT, AS THEY SAY, IS THAT ---------- ]]]]]]]

The story genre is "Fantasy".
The story headline is "A Rockin['] Homebrewed ENCOUNTER CRITICAL Quest".
The story description is "Once upon a time, there was a story description that needed a good re-write.".
The story creation year is 2010.
The release number is 3.

Volume of Foundations and Preliminaries

Use MAX_PROP_TABLE_SIZE of 500000.

Release along with the source text.

Book of Inclusions

Chapter of List Control

Include List Control by Eric Eve.

[The following bit of code makes List Control usable for random strings that appear within a sentence - something ToaSK, and by extension ToaUROD, depends on]

To show the next response from  (tab - a table-name):
  let r be the relevant row of tab;
  choose row r in tab;
  say "[response entry]"

Before printing the name of the MEADOW: say "[one of][line break][line break][or][stopping]";

Chapter of Things That Aren't List Control At All

Include Basic Screen Effects by Emily Short.

Book of Extensions Which Require Some Up-Front Fiddling

Include Extended Banner by Stephen Granade.
   When play begins: change the story copyright string to "2009".

Include Punctuation Removal by Emily Short.
   After reading a command: remove stray punctuation.

Chapter of the Plurality Extension (and Related Stuff)

Include Plurality by Emily Short.
   After printing the name of a thing (called the referee): have the parser notice the referee.

Book of Checks and Warnings

When play begins:
   if screen width is less than 45 begin;
   say paragraph break;
   say "Your display is [screen width] columns wide. This is a bit cramped for this story: the status bar cannot display your Quest Rate and Hit Points at this size (use the [b]HIT POINTS[n] and [b]SCORE[n] commands in play as needed). The game will otherwise function normally.";
   say paragraph break;
   say "(press any key)";
   wait for any key;
   clear screen;
   end if;

Book of Preliminary Facts and Shuffles

The time of day is 8:55 PM.

When play begins:
   sort the Table of Anywhere Atmospherics in random order;
   sort the Table of Duder in random order;
   sort the Table of DudeUP in random order;
   sort the Table of Dunroamin in random order;
   sort the Table of DunUP in random order;
   sort the Table of Footloose in random order;
   sort the Table of FootUP in random order;
   sort the Table of Huronian Portions in random order;
   sort the Table of Indoor Atmospherics in random order;
   sort the Table of Outdoor Atmospherics in random order;
   sort the Table of Generic Errors in random order;

Rule for printing the banner text:
   say "[bold type][story title][roman type][line break]";
   say "[story headline][line break]";
   say "Release [release number] / CogniKing SN-[story serial number] / I7-[I7 version number]";
   say line break; say line break;
   say "Portions of this game appeared originally in [b]Treasures of a Slaver[']s Kingdom[n], copyright (c) 2007,2008 by S. John Ross, and appear here by permission. [quotation mark]Encounter Critical[quotation mark] and terms unique to it are trademarks of S. John Ross.";
   say line break;

When play begins:
   Now nobanner is 1;
   Change right alignment depth to 22;
   change indicate-unvisited to dont-show-unvisited;
   say paragraph break;
   say "[bold type][story title][roman type][line break]";
   say "[story headline][line break]";
   say "Which, While Unauthorized, Is Entirely Awesome Nevertheless";
   say line break;
   say "Release [release number] / CogniKing SN-[story serial number] / I7-[I7 version number]";
   say paragraph break;
   say "'... In the science-swept world of VANTH, a young BARBARIAN has another adventure, which should probably have some sort of teaser-text right here, describing the game's overall goal in simple terms, maybe with a flimsy motivation implied, and ending with an exclamation mark!";
   say paragraph break;
   say "[italic type]Depress a key to continue, mighty BARBARIAN!     [roman type]";
   wait for any key;
   move the player to the location of the player, without printing a room description;
   clear the screen;

Nobanner is a number variable.
   Rule for printing the banner text when nobanner is 1: say "[run paragraph on]";
   After printing the name of the MEADOW: now nobanner is 0;

Volume of Dumbing-Down the Parser (and Smartening It Up)

Book of Does the Player Mean

Does the player mean conversing with a person: it is likely.
Does the player mean attacking a foe: it is very likely.
Does the player mean attacking something which is not a person: it is very unlikely.
Does the player mean using a suit which is not carried: it is likely.
Does the player mean using a weapon which is not carried by a person: it is very likely.
Does the player mean using a weapon which is the ReadyWeapon: it is likely.
Does the player mean placelooking the location of the player: it is very likely.
Does the player mean placelooking an adjacent room: it is very likely.
Does the player mean namegoing an adjacent room: it is very likely.

Book of Fundamental Digital Stupidities

The description of a thing is usually "[one of][GDSC1][or][GDSC2][or][GDSC3][or][GDSC4][or][GDSC5][or][GDSC6][or][GDSC7][in random order][run paragraph on]".
   To say GDSC1: say "You [one of]see[or]espy[or]notice[or]sense[in random order] nothing [one of]unusual[or]remarkable[or]eye-catching[or]special[in random order] about the [noun].";
   To say GDSC2: say "It[']s [one of]just[or]only[in random order] [a noun][one of], but [it-they] hath a certain charm[or], like any other[or], with all that entails[in random order].";
   To say GDSC3: say "It[']s the finest example of [a noun] you[']ve seen since you were enslaved.";
   To say GDSC4: say "[Cap it-they of the noun] remind[s] you of [a noun] from your childhood.";
   To say GDSC5: say "Now that you mention it, [it-they] really [is-are] a [italic type][one of]sinister[or]peculiar[in random order][roman type] example of [a noun].";
   To say GDSC6: say "It reminds you of the old [one of]folktale about[or]legend of[or]tavern tale about[or]fable of[in random order] the [one of]maiden[or]crone[or]unicorn[or]scholar[or]pickpocket[or]ASTEROID WORM[in random order], the [noun], and the [one of]razing of GOD CITY[or]murder of the FIRST HOBLING EMPEROR[or]rise of DARTH VIRAXIS[or]the fall of the SKY-MONSTERS from the GALAXY[or]naughty vicar[in random order].";
   To say GDSC7: say "You can[']t see any [noun] here![paragraph break]Oh, wait, there [it-they] [is-are]. Perfectly ordinary [noun].";

The description of a person is usually "[one of]You notice nothing exotic, enthralling, sexy or unusual about [the noun], at least by barbarian standards.[or][']Tis but [a noun] like any other.[or]If thou hast seen one [noun], thou hast seen them all.[cycling]"

Check using a person:
   say "Unless thou dost intend something kinky, you can fathom no immediate use for [the noun]." instead;

Instead of doing anything except examining, taking, conversing with, using or attacking to a person, say "[generic-error]" instead.

Before going nowhere: say "No good path leads that way, and thou art not of the Pioneer class!" instead.

Rule for printing a parser error: say "[generic-error]"

Chapter of Scenery Rules

A thing can be unattainable. [a view of the mountain]
A thing can be unenterable. [a glimmer of light]

Before doing anything except examining or entering a thing that is scenery, say "[one of]I[']ve seen this tragedy before. The alluring proximity of [a noun] can drive many a hero to gibbering madness.[or]Creative! But fruitless.[or]Thou hast barkest up the wrong tree, barbarian.[or]Thy savage might and lust for vengeance could be put to better use than that, barbarian.[or]When thy saga is writ and thy story told and maidens swoon to hear it, the tale-tellers will, in kindness and in mercy, skip the part where [the noun] hath distracted thee so.[in random order]" instead;

Check entering a thing that is unattainable:
  say "That is well beyond thy reach, barbarian." instead;

Check entering a thing that is unenterable:
  say "You're a strange one, barbarian." instead;

Chapter of the Screen-Clearing Mania

Before going: clear the screen.
After going:
   say line break;
   try looking;

Chapter of the Generic Error Message

To say generic-error:
   Show the next response from the Table of Generic Errors;
   say " [one of]Refer to your game manual for assistance.[or]The HELP command may offer some remedy.[or]Your game manual, or the HELP command, might give aid and succor.[or]Seek guidance with the HELP command.[or][line break][as decreasingly likely outcomes]";

Table of Generic Errors
response
"Prithee pardon, barbarian?"
"This computeth not."
"You speak madness, barbarian!"
"Bestead thy plight and becalm mine own misdoubt! I would fain hear plain ACTION COMMANDS, marry-ed unto reasonable nouns! Sooth!"
"From any but a barbarian, I would presume such a command SORCERY most perplexing!"
"I beggest thy pardon?"
"Thou art a barbarian, [']tis true, but even thou canst masterest wise use of the ACTION COMMANDS."
"Thou hast exceeded the limits of SCIENTIFIC TECHNO-REASONING."
"[one of]Take care to consider[or]Striveth for wisdom in[or]Select with care[or]Choose carefully[in random order] [one of]thy[or]thine[or]your[in random order] [one of]reasoning[or]words[or]commands[or]endeavors[in random order], barbarian."
"By Huron's [huronstuff]! I am [one of]vexed[or]perplexed[or]lain low[or]defeated[at random] by thine [one of]illogic[or]riddles[or]disarray[or]folly[or]hullabaloo[or]dementia[as decreasingly likely outcomes]!"
"[one of]Nonsense[or]Poetics[or]Bedlam[or]Perplexity[as decreasingly likely outcomes] and [one of]illogic[or]riddles[or]disarray[or]folly[or]hullabaloo[or]dementia[as decreasingly likely outcomes]!"
"Art thou [one of]addled[or]mutated with a self-consuming brain[or]head-wounded[or]in thy cups[or]vexed[or]confusest-ed[as decreasingly likely outcomes]?"
"A [one of]pox[or]vexation[or]hex[or]whammy[or]double-whammy[as decreasingly likely outcomes] [one of]on[or]upon[purely at random] [one of]your[or]thy[or]thine[at random] [one of]foolish[or]accursed[or]wicked[or]demonic[or]cruel[at random] keyboard!"
"I attaint thee, varlet! Thy [one of]verbiage[or]vocabulary[or]wicked language[or]mind[as decreasingly likely outcomes], it affrighteth me!"
"The [one of]phasic radiation[or]dream of vengeance[or]bloodlust[or]need for justice[or]aprismatic sub-planetary wavelengths[as decreasingly likely outcomes] must be clouding your thoughts, barbarian."
"The dullest [one of]Klengon[or]Wooky[or]Planetary Ape[or]Frankenstein[or]mud-pie merchant[or]castle guard[or]youngling[or]SLUDGE AMOEBA[as decreasingly likely outcomes] can do better than that."

Book of Something New And Unwanted

Understand the command "adjust" as something new.
Understand the command "answer" as something new.
Understand the command "ask" as something new.
Understand the command "attach" as something new.
Understand the command "awaken" as something new.
Understand the command "bathe" as something new.
Understand the command "bother" as something new.
Understand the command "brief" as something new.
Understand the command "burn" as something new.
Understand the command "buy" as something new.
Understand the command "check" as something new.
Understand the command "clean" as something new.
Understand the command "clear" as something new.
Understand the command "climb" as something new.
Understand the command "close" as something new.
Understand the command "consult" as something new.
Understand the command "cover" as something new.
Understand the command "cross" as something new.
Understand the command "curses" as something new.
Understand the command "cut" as something new.
Understand the command "damn" as something new.
Understand the command "darn" as something new.
Understand the command "dig" as something new.
Understand the command "display" as something new.
Understand the command "disrobe" as something new.
Understand the command "dive" as something new.
Understand the command "doff" as something new.
Understand the command "don" as something new.
Understand the command "drag" as something new.
Understand the command "drat" as something new.
Understand the command "drink" as something new.
Understand the command "dust" as something new.
Understand the command "eat" as something new.
Understand the command "embrace" as something new.
Understand the command "fasten" as something new.
Understand the command "feed" as something new.
Understand the command "feel" as something new.
Understand the command "fill" as something new.
Understand the command "fix" as something new.
Understand the command "from" as something new.
Understand the command "fuck" as something new.
Understand the command "full score" as something new.
Understand the command "fullscore" as something new.
Understand the command "get off" as something new.
Understand the command "give" as something new.
Understand the command "hear" as something new.
Understand the command "hop" as something new.
Understand the command "insert" as something new.
Understand the command "jump" as something new.
Understand the command "kiss" as something new.
Understand the command "light" as something new.
Understand the command "listen" as something new.
Understand the command "lock" as something new.
Understand the command "long" as something new.
Understand the command "move" as something new.
Understand the command "nap" as something new.
Understand the command "no" as something new.
Understand the command "normal" as something new.
Understand the command "offer" as something new.
Understand the command "open" as something new.
Understand the command "pay" as something new.
Understand the command "polish" as something new.
Understand the command "present" as something new.
Understand the command "press" as something new.
Understand the command "prune" as something new.
Understand the command "pull" as something new.
Understand the command "purchase" as something new.
Understand the command "push" as something new.
Understand the command "put" as something new.
Understand the command "read" as something new.
Understand the command "remove" as something new.
Understand the command "rotate" as something new.
Understand the command "rub" as something new.
Understand the command "say" as something new.
Understand the command "scale" as something new.
Understand the command "screw" as something new.
Understand the command "scrub" as something new.
Understand the command "search" as something new.
Understand the command "set" as something new.
Understand the command "shift" as something new.
Understand the command "shine" as something new.
Understand the command "shit" as something new.
Understand the command "short" as something new.
Understand the command "shout" as something new.
Understand the command "show" as something new.
Understand the command "shut" as something new.
Understand the command "sing" as something new.
Understand the command "sip" as something new.
Understand the command "sit" as something new.
Understand the command "skip" as something new.
Understand the command "sleep" as something new.
Understand the command "slice" as something new.
Understand the command "smell" as something new.
Understand the command "sniff" as something new.
Understand the command "sorry" as something new.
Understand the command "speak" as something new.
Understand the command "squash" as something new.
Understand the command "squeeze" as something new.
Understand the command "stand" as something new.
Understand the command "superbrief" as something new.
Understand the command "swallow" as something new.
Understand the command "sweep" as something new.
Understand the command "swing" as something new.
Understand the command "switch" as something new.
Understand the command "switch" as something new.
Understand the command "taste" as something new.
Understand the command "think" as something new.
Understand the command "throw" as something new.
Understand the command "throw" as something new.
Understand the command "tie" as something new.
Understand the command "touch" as something new.
Understand the command "turn" as something new.
Understand the command "turn off" as something new.
Understand the command "turn on" as something new.
Understand the command "twist" as something new.
Understand the command "uncover" as something new.
Understand the command "unlock" as something new.
Understand the command "unlock" as something new.
Understand the command "unscrew" as something new.
Understand the command "unwrap" as something new.
Understand the command "verbose" as something new.
Understand the command "wake up" as something new.
Understand the command "wake up" as something new.
Understand the command "wake" as something new.
Understand the command "watch" as something new.
Understand the command "wave" as something new.
Understand the command "wear" as something new.
Understand the command "wear" as something new.
Understand the command "wipe" as something new.
Understand the command "y" as something new.
Understand the command "yes" as something new.

[Understand the command "consult" as something new.
Understand the command "answer" as something new.] [moved after Exit Lister inclusion]

Book of SAVE Limitations

SVCNT is a number variable. SVCNT is 0.

Check saving the game:
   if 1 is 1, increase SVCNT by 1;
   if CourVariable is 1 and SVCNT > 3, say "Thou hast used all the SAVES permitted thee in COURAGE mode, barbarian." instead;
[   if the SEA-MONSTER'S GULLET is the location of the player, say "You're too busy dissolving in DIGESTIVE JUICES to SAVE." instead;] [sample of SAVE-restricted area]
   if the FoeFum is touchable, say "You may not SAVE with [the FoeFum] right here watching you." instead;
   if the HP of the Player < MaxHP of the Player and a Foe is touchable, say "[']Twould be unwise, barbarian, to SAVE without thy full Hit Points with [a random foe in the location of the player] so near." instead;
[   if the Piranha-School Special is happening, say "[']Twould be [italic type]most[roman type] unwise to SAVE whilst SKY PIRANHA hunteth thee." instead;] [sample of SAVE-restricted scene]

Book of Kinds and Qualities and Other STUFF Foundations

A thing can be unremotable. Before using an unremotable thing when the noun is not enclosed by the player, say "In thine eye is not the same, barbarian, as in thy hand. Well, unless thou dost stab thine own eye with a DAGGER, perhaps, but thou, as a rule, dost not. If thou canst SEIZE [the noun], then thou canst USE [the noun]. Alas." instead;

Volume of THE CORE GAME ACTIONS

After reading a command:
   if the player's command includes "the " begin;
   cut the matched text;
   end if.

Before dropping something:
[   if the location of the player is the PIRATE SHIP, say "It occurs to you that this SHIP could sail away at any time, taking [the noun] away forever." instead;] [... and so on for game-breaking drops]
   if the noun is worn by the player begin;
      try using the noun;
   end if;

Book of the JOURNEY (Go) Command

Understand the commands "JOURNEY", "FLEE", "ESCAPE" and "RETREAT" as "go".

After reading a command:
   if the player's command matches "enter" begin;
      try going inside instead;
   end if.

Check going:
   if WimpVar < 2 and RegularBar is 0 and HP of Player < MaxHP of Player / 4 begin;
      say "[line break][line break][line break]By Huron's [huronstuff]! You try to [one of]flee[or]run[or]retreat[purely at random], but [one of]thine eyes are blinded by thine own blood and rage[or]thine legs fail thee in thy battered state[or]thou art too wounded to maneuver[at random]! You must fight ... or be vanquished!" instead;
   end if;

Chapter of Entering People

Before entering a woman: try using the noun instead;
Before entering a man: say "This adventure is naughty, barbarian, but not THAT naughty." instead;
Before entering yourself: say "Thou art gifted, but not THAT gifted." instead;
Before entering a foe: say "A lover, not a fighter, eh? [The noun] really isn[']t your type, barbarian." instead;
Before entering a person: say "Very kinky! But no." instead;

Book of the SEIZE (Take) Command

Understand the commands "SEIZE" and "SIEZE" as "take".

After reading a command: if the player's command matches "PILLAGE", replace the player's command with "take all";

Chapter of the DROP Command

After reading a command: if the player's command matches "SHED", replace the player's command with "drop all";

Book of the REGARD (Look/At) Command

Understand "REGARD" or "R" as looking.

Understand "REGARD [something]" or "R [something]" as examining.

Book of the PARLEY (Talk to) Command

To say chatterbox: say "[one of]chat with[or]talk to[or]PARLEY with[or]speak with[or]converse at length with[or]converse with[at random]";

Conversing with is an action applying to one thing. Understand "Parley with/at [something]" or "Talk to/with/at [something]" or "Speak with/to/at [something]" or "Parlay with/at [something]" or "Chat with/at [something]" as conversing with.

Before conversing with:
   change ATMOV to -2;

Check conversing with:
   if the noun is not a person, say "[one of]You begin to [chatterbox] [the noun], but it escalates into a pointless argument, and since it[']s difficult for [a noun] to apologize, things are left unresolved.[or]You are a strange one, barbarian.[or]You [chatterbox] [the noun]. It must be very lonely, being a barbarian.[or]When you were a child, you would [chatterbox] [a noun] for hours on end. But your mother dropped you a lot.[at random]" instead;

Carry out conversing with:
   say "[The noun] nods politely, impressed by your barbaric elocution."

Book of the USE Command

Using is an action applying to one thing. Understand "Use [something]" or "[something]" as using.

Carry out using: say "[UtilityFailure].";

Before using when the noun is enclosed by a person and the noun is not enclosed by the player, say "[The noun] is not yours to toy with, barbarian." instead;

To say UtilityFailure: Show the next response from the Table of Utilized Mockery.

Table of Utilized Mockery
response
"You experiment with [the noun] for a while, but achieve little"
"You gain new respect for the elders of your village, who could use [a noun] much more expertly than you"
"You stare at [the noun] as hard as you can, but it only makes your eyes hurt. Alas, the ways of the barbarian, while hallowed by the ages and kin to the wild, are so seldom useful"
"[The noun] resist[s] your every attempt to use [it-them] constructively"
"Nothing useful happens, but sometimes it[']s nice to just spend some quiet time with [a noun]"
"At first your attempts seem doomed to failure, but then it occurs to you that you could try sneaking up on [the noun] and shouting. Sadly, this too produces no useful result"
"Nothing useful happens, and [the noun] seem[s] to mock you with condescending silence. You come to hate [the noun], and vow vengeance upon [it-them], just as soon as you are finished with thy quest"
"You point your finger at [the noun], and concentrate. You determine from this that you are no Warlock, but only a Warrior-born"

Book of the USE WITH Command

Using it with is an action applying to two things. Understand "Use [something] with/on/plus/and/&/in/over/under/w/beside/alongside [something]" as Using it with. Understand "Use [something] with/on/plus/and/&/in/over/under/w/beside/alongside [any room]" as Using it with.

Check using it with:
   if the noun is the second noun, say "Don[']t injure yourself on the recursivity, barbarian." instead;
   if the second noun is a room, say "You need not USE things with PLACES, barbarian. To (for example) USE [the noun] with [the location of the player], simply JOURNEY to [the location of the player] and type USE [the noun]. Of course, thou art already standing here at [the location of the player], but thou gettest my meaning, I am sure." instead;
   if the noun is the THESKIAN DUFFEL BAG or the second noun is the THESKIAN DUFFEL BAG, try using the THESKIAN DUFFEL BAG instead;
   if the noun is the player, say "Kinky." instead;
   if the noun is TRIVIA or the second noun is TRIVIA, try using TRIVIA instead;
   if the noun is enclosed by a person and the noun is not enclosed by the player, say "[The noun] is not yours to toy with, barbarian." instead;
   if the noun is worn by the player and the second noun is a container begin;
      now the noun is carried by the player;
   end if;
   if the second noun is the player, try using the noun instead;
   if the noun is not enclosed by the player, say "[The noun] [is-are] not yours to toy with, barbarian. [if the second noun is enclosed by the player][The second noun], however, [is-are] yours to do with as you please.[otherwise]Neither [is-are] [the second noun].[end if][if the second noun is not enclosed by the player and the noun is enclosed by the player][line break][end if]" instead;

Carry out using it with:
   say "[ComboFailure]. [if the second noun is a foe][The second noun] takes this opportunity to consider new ways to harm you.[end if][if the noun is a weapon](If you mean to do violence unto [the second noun], employ the ASSAIL command.)[end if][if the noun is not a weapon][line break][end if]";

To Say ComboFailure: Show the next response from the Table of Combo Mockery;

Table of Combo Mockery
response
"You turn [the noun] this way and that, considering [its-their] possible combinations with [the second noun]. You extend your thumb for comparison, because you saw a DWARF do that once and it looked pretty cool"
"Your barbaric experience hasn't provided any useful way to use [a noun] with [a second noun], at least without a shaman to oversee the procedure"
"The combination of [the noun] and [the second noun] solves nothing, but you find yourself noticing that, visually, it's quite a fetching juxtaposition"
"If there's a way to constructively use [a noun] with [a second noun], you can't quite manage it"
"[The noun] and [the second noun] don't mesh in any useful way, despite your very fiercest battle-cry in the attempt"
"You've heard tales of how HURON, the GOD OF BEING A VERY MIGHTY GOD, once used [a noun] with [a second noun] to [one of]defeat a thousand enemy kings[or]conquer the mythical realm of ARAGASSIA[or]lay waste to the DEMON-THEATER of THRINGOTH[or]bring peace to the ENDLESS BATTLEFIELD of NOONG[or]divert the JAVADRA RIVER into the GODLY LAVA-PITS of XOOR[or]woo the UNWOOABLE MAIDENS of the SKY BROTHEL of SNIRRA[or]carve his initials atop the SEVEN MILE PILLARS of HARAGORN[in random order]! Now that you think of it, though, the tale seemed to gloss right past the critical details"
"You try a number of things, including [one of]glaring at[or]singing to[or]shouting at[or]breathing on[or]making obscene thrusting gestures toward[or]scowling at[at random] [the second noun] while [one of]flexing your [LOR] thigh muscle at[or]rotating your [LOR] buttock at[or]winking your [LOR] eye at[or]dancing for the amusement of[or]reciting a great OATH at[or]clenching your [LOR]-side pectoral muscles at[at random] [the noun]. I[']d be [one of]leading you on[or]teasing most cruelly[or]lying[or]stretching the truth[or]remiss[at random] if I said the results are useful"

To say LOR: say "[one of]left[or]right[purely at random]"

Book of the ASSAIL (Attack) Command

Understand "ASSAIL [something]" or "STRIKE [something]" or "CLEAVE [something]" or "SLAUGHTER [something]" or "SLAP [something]" or "PUNCH [something]" or "BACKHAND [something]" or "BATTLE [something]" or "SLAY [something]" or "FIGHT [something]" or "DUEL [something]" as attacking.

Chapter of ATTACK Preliminaries

damtotal is a number variable. [monster damage less the autoheal]
damreport is a number variable. [1 or 0 to determine the damage report line]
PCLO is a number variable. [the PC's low damage roll]
PCHI is a number variable. [the PC's high damage roll]
PROB is a number variable. [the current odds simplified to one word so as not to confuse Inform]
MYST is a number variable. [whether or not the player missed (ha!) an attack]
RegularBar is a number variable. [for toggling the Status Bar to battle mode]
DRT is a number variable. [used for calculating armor benefits turn by turn]
DRB is a number variable. [used for calculating armor benefits turn by turn]

PCLO is 1. PCHI is 6. RegularBar is 1. DRT is 0. DRB is 100.

Chapter of FOE Rules

A foe is a kind of person. A foe has a number called HP. A foe has a number called MaxHP. A foe has some text called Attack-Declare. A foe has some text called Miss-Declare. A foe has some text called ByeNow. A foe has a number called FoeSkill. A foe has a number called MinWhup. A foe has a number called MaxWhup.

Understand "foe/enemy/opponent/rival" or "beast/beasts/monster/creature/it/them/him" as a foe. A foe is usually male. A femfoe is a kind of foe. A femfoe is female.

Understand "her" as a femfoe.
Understand "woman" as a femfoe.
Understand "wench" as a femfoe.
Understand "man" as a foe.
Understand "person" as a person.
Understand "girl" as a femfoe.
Understand "maid" as a femfoe.
Understand "lass" as a femfoe.

The WORTHY OPPONENT is a foe. [Should never appear in play, used as a dummy FoeFum]

The FoeFum is a thing that varies. The FoeFum is the WORTHY OPPONENT. Before attacking a foe (called the tarjay): change the FoeFum to the tarjay.

Before going when the FoeFum is not touchable and the HP of the FoeFum is less than the MaxHP of the FoeFum:
   now the HP of the FoeFum is the MaxHP of the FoeFum;

Check Conversing with a foe:
   say "[The noun] seems more interested in sizing you up for weaknesses with intent to vanquish you." instead;

Before Taking:
   if the noun is a foe, say "[The noun] is not so easily taken!" instead;
   if the FoeFum is touchable, say "You are faced with a foe, barbarian." instead;

Check Using a foe:
   say "If you're going to use [the noun] at all, it might be best to use [the noun] as target practice." instead;

Chapter of the Basic Fighting Routine

Every turn when the location of the FoeFum is the location of the player:
   If a random chance of the FoeSkill of the FoeFum in 100 succeeds begin;
      Let the FoeDam be a random number between
         the MinWhup of the FoeFum and
         the MaxWhup of the FoeFum;
      Decrease the HP of the player by the FoeDam;
      Say "[Attack-Declare of the FoeFum]";
      Say "[italic type] You have suffered [FoeDam][if FoeDam > 1] hits of [end if][if FoeDam is 1] hit of [end if]damage![roman type]";
      Say line break;
   Otherwise; say "[Miss-Declare of the FoeFum][line break]";
   End if;

Chapter of WEAPON Rules

A weapon is a kind of thing. Understand "weapon/blade" as a weapon.
   A weapon has a number called LoDam. The LoDam of a weapon is usually 1.
   A weapon has a number called HiDam. The HiDam of a weapon is usually 6.
   A weapon can be wielded or unwielded. A weapon is usually unwielded.
   A weapon can be titanic.
   A weapon can be cageworthy.

The DefaultWeapon is a thing. Rule for printing the name of the DefaultWeapon: say "bare, callused FIST".

The ReadyWeapon is a thing that varies. The ReadyWeapon is the DefaultWeapon.

Check using a weapon:
   let cointoss be 0;
   [--- WEAPON NOT YET CARRIED ---]
   if the noun is not carried by the player begin;
      silently try taking the noun;
   end if;
   [--- USING A WIELDED WEAPON ---]
   if the noun is wielded begin;
      now the noun is unwielded;
      now the ReadyWeapon is the DefaultWeapon;
      now PCLO is 1;
      now PCHI is 6;
      say "You unhand [the noun] and carry it as ordinary gear. Your bare FIST is ready for battle!" instead;
      end if;
   [--- USING AN UN-WIELDED WEAPON ---]
   if the noun is unwielded begin;
      if the player encloses a wielded weapon (called the zarf) and the noun is carried begin;
         let cointoss be 1;
         say "You hang [the zarf] at your side, and grasp instead";
         now the zarf is unwielded;
      end if;
      if the noun is not carried, say "[line break]You do not possess [the noun]." instead;
      now the noun is wielded;
      now PCLO is the LoDam of the noun;
      now PCHI is the HiDam of the noun;
      change the ReadyWeapon to the noun;
      say "[if cointoss is 0]You heft[end if] [the noun][if cointoss is 0] in your mighty hand[end if], prepared for battle!" instead;
      end if;

After printing the name of a weapon when taking inventory: say "[if wielded] (held at the ready)[otherwise] (currently un-used)[end if]"

Before dropping the ReadyWeapon: say "You wield [the noun], and must either unready it with the USE command, or USE an alternate weapon in its stead." instead;

Chapter of ARMOR Rules

A suit is a kind of thing. Understand "armor/armour/suit" or "suit of armor" or "suit of armour" as a suit.
   A suit has a number called DRTop. The DRTop of a suit is usually 35.
   A suit has a number called DRBottom. The DRBottom of a suit is usually 100.
   A suit can be girded or ungirded. A suit is usually ungirded.

The DefaultArmor is a thing. Rule for printing the name of the DefaultArmor: say "only your rippling, well-tanned SKIN".

The ReadyArmor is a thing that varies. The ReadyArmor is the DefaultArmor.

Check entering a suit:
   say "To don a suit of armor, barbarian, employ the USE command." instead;

Check using a suit:
   let cointoss be 0;
   if the FoeFum is touchable begin;
      say "[The FoeFum] is right here! You are quick, barbarian, but not [italic type]that[roman type] quick." instead;
   end if;
   if the noun is not carried by the player begin;
      silently try taking the noun;
   end if;
   if the noun is girded begin;
      now the noun is ungirded;
      now the ReadyArmor is the DefaultArmor;
      now DRT is 0;
      now DRB is 100;
      say "You remove [the noun] and place it with your carried gear. Now you are un-armored." instead;
      end if;
    if the noun is ungirded begin;
       if the player encloses a girded suit (called the fraz) and the noun is carried begin;
          let cointoss be 1;
          say "[IPOHP]You remove [the fraz], and replace it with";
          now the fraz is ungirded;
       end if;
       if the noun is not carried, say "[line break]You do not possess [the noun]." instead;
          now the noun is girded;
          now DRT is the DRTop of the noun;
          now DRB is the DRBottom of the noun;
          change the ReadyArmor to the noun;
          say "[if cointoss is 0]You don[end if] [the noun]. [IPOHP]Now you are well-suited for bloody mayhem!" instead;
       end if;

To say IPOHP:
[   if the location is not the (location that damages the player) begin;] [fill this out for auto-damage zones]
      change the HP of the Player to 2500;
[      end if;] [pairs with the above]

After printing the name of a suit when taking inventory: say "[if girded] (being worn)[otherwise] (currently un-used)[end if]"

Before dropping the ReadyArmor: say "You are cloth-ed in it, and must un-suit (with the USE command) before discarding it." instead;

Section of the PROWESS Command

Wepping is an action out of world. Understand ["METTLE" or] "PROWESS" or "P" [or "PRO"] as wepping. AVA is a number variable. AVA is 100. AVB is a number variable. AVC is a number variable.

Carry out wepping:
   Change AVB to AVA multiplied by DRT;
   CHANGE AVC to AVB divided by DRB;
   say "You wield [if the player encloses a wielded weapon]the [otherwise]only your [end if][ReadyWeapon]. Adjusting for your abilities and [if SCORE > 454]experience[otherwise]progress[end if], you do from [PCLO + Bonus of the Player] to [PCHI + Bonus of the Player] points of damage with each successful blow. Your odds of striking true are [Skill of the player]%[SKILLPENALTIES]. Your armor is [if the player encloses a girded suit]the [end if][ReadyArmor][if the player encloses a girded suit], which increases your Hit Points by [AVC]%[end if]. [if HP of Player < MaxHP of Player]Your current Hit Points are [HP of Player] (out of [MaxHP of Player]).[otherwise]You are uninjured, with your full complement of [MaxHP of Player] Hit Points. A mighty Warrior, indeed!"

To say SKILLPENALTIES:
   say "[if LOADPENALTY > 0] (burdened somewhat by your load)[end if]";

HitPointChecking is an action out of world. Understand "HP" or "Hit Points" as HitPointChecking. Carry out HitPointChecking: say "[if HP of Player < MaxHP of Player]Your current Hit Points are [HP of Player] (out of [MaxHP of Player]).[otherwise]You are uninjured, with your full complement of [MaxHP of Player] Hit Points."

Chapter of Actually ATTACKING Stuff

The block attacking rule is not listed in any rulebook.

Check attacking:
   If the noun is not a foe, say "[The noun] is not your foe, barbarian." instead;

Carry out attacking:
   clear the screen; clear the screen; now RegularBar is 0;
   say line break; say line break; say line break;
   Change PROB to the Skill of the Player;
   Change MYST to 1;
   if a random chance of PROB in 100 succeeds begin;
      let the BaseDamage be a random number between PCLO and PCHI;
      let the PCDamage be BaseDamage + Bonus of the Player;
      decrease the HP of the noun by PCDamage;
      if the HP of the noun is less than 0, change the HP of the noun to 0;
      Change MYST to 0;
      say "[BarbarianAttack][italic type] You scored [PCDamage] points of damage[if the HP of the noun < 1], leaving [the noun] at your mercy![paragraph break][end if][if the HP of the noun > 0]![end if][roman type]";
   end if;
   if MYST is 1, say "[BarbarianMiss][line break]";
   if the HP of the noun < 1 begin;
      if the noun is an item listed in the Table of Object Values begin;
         award score entry points;
         blank out the whole row;
         end if;
      now RegularBar is 1;
      say "[The noun] [is-are] defeated![paragraph break]";
      remove the noun from play;
      say "[The ByeNow of the FoeFum][line break]";
      say line break;
      say "[italic type](press a key when ready)[roman type]     ";
      wait for any key;
      clear the screen;
      say line break;
      try looking;
   end if;

To Say BarbarianAttack: Show the next response from the Table of Barbarian Mayhem.
To Say BarbarianMiss: Show the next response from the Table of Barbarian Bloopers.
To Say huronstuff: Show the next response from the Table of Huronian Portions.

Table of Barbarian Mayhem
response
"Sa-ho! You give [the FoeFum] a sampling of your [readyweapon], but good!"
"You attack!"
"By Huron's [huronstuff], you strike hard and true!"
"You leap, and strike!"
"By Huron's [huronstuff], your [readyweapon] lands home!"
"A skillful attack if you do say so yourself!"
"You lunge deep, and strike!"
"By Huron's [huronstuff]! A mighty blow!"
"You attack with all your might!"
"Your foe is astonished by your speed as you strike hard!"
"By Huron's [huronstuff], a fine hit!"
"You hit hard, snarling with rage!"
"You lash out with the rage of your barbarian ancestors!"
"By Huron's [huronstuff], a blow to be remembered!"
"Sa-ho! A mighty attack!"
"Taste barbarian rage, [FoeFum]!"

Table of Barbarian Bloopers
response
"By Huron's [huronstuff]! A miss!"
"You miss!"
"You could have sworn your aim was true, but your quarry was already elsewhere! A miss!"
"By Huron's [huronstuff]! Thine arm hath failed thee!"
"You are quick, but your foe was quicker that time. A miss!"
"Your attack is too hasty, and it fails!"
"By Huron's [huronstuff]! Thine aim hath failed thee!"
"A miss! BAH!"
"You were too slow that time. A miss!"
"Damn and blast! A miss!"
"By Huron's [huronstuff]! Thou hast missest!"
"A thousand curses on these foolish percentile dice! A miss!"
"Curses! A miss!"

Table of Huronian Portions
response
"agreeable ass-dandruff"
"boundless eyebrow"
"center nostril"
"embryonic egg-flap"
"indigestible excretions"
"non-Euclidean necktie"
"panoptic pudenda"
"parsimonious pansophism"
"storm-frosted comb-over"
"twice-plaited nostril braids"
"vacticinal cowlick"

Book of CHEATS and EXTRAS

Section of the UNDOCUMENTED OATH COMMAND

Oathing is an action out of world. Understand "Oath" or "Huron" as oathing. Carry out oathing: say "By Huron[']s [huronstuff]!";

Volume of Program Commands

Book of the COURAGE Command

WimpVar is a number variable. WimpVar is 0.
CourVariable is a number variable. CourVariable is 0.
WIMPT is a number variable. WIMPT is 1. 
WIMPB is a number variable. WIMPB is 1. 
   [WIMPT(op) / WIMPB(ottom) is the formula applied to both the barbarian's Hit Points and the barbarian's Score-derived damage bonus]

Couraging is an action applying to nothing. Understand "Courage" as couraging.

Carry out Couraging:
   if CourVariable is 1 begin;
      say "You're already [italic type]in[roman type] COURAGE mode, barbarian, but your enthusiasm is admirable." instead;
   end if;
   say "This game is now in COURAGE mode, limiting the game to no more than three SAVE commands from here forward, and LOCKING the game into fully authorized [bold type]ENCOUNTER CRITICAL[roman type] difficulty levels. Congratulations, barbarian; you are an adventurer of true mettle!";
   Change WimpVar to 0; Change WIMPT to 1; Change WIMPB to 1;
   change HP of the Player to HP of the Player * WIMPT;
   change HP of the Player to HP of the Player / WIMPB;
   change SVCNT to 0;
   change CourVariable to 1 instead;

Book of the OFFICIAL and APPRENTICE and WIMP Commands

Officializing is an action applying to nothing. Understand "Official" as Officializing.

Carry out Officializing:
   if CourVariable is 1 begin;
      say "In COURAGE mode, official difficulty is insured." instead;
      end if;
   if WimpVar is 0 begin;
      say "You are already in OFFICIAL combat-difficulty mode." instead;
      end if;
   Change WimpVar to 0; Change WIMPT to 1; Change WIMPB to 1;
   Say "Battle difficulty & player dignity restored to official Encounter Critical standards. For an even greater challenge, try COURAGE mode, which enforces official difficulty (locking out the APPRENTICE and WIMP commands) and limits reliance on SAVE.";
      change HP of the Player to HP of the Player * WIMPT;
      change HP of the Player to HP of the Player / WIMPB;

Apprenticizing is an action applying to nothing. Understand "Apprentice" as Apprenticizing.

Carry out apprenticizing:
   if CourVariable is 1 begin;
      say "You have locked this game in COURAGE mode, preventing access to that command." instead;
      end if;
   if WimpVar is 1 begin;
      say "You are already in APPRENTICE combat-difficulty mode." instead;
      end if;
   Change WimpVar to 1; Change WIMPT to 4; Change WIMPB to 3;
   Say "Battle difficulty switched to APPRENTICE mode (barbarian Hit Points above-average).";
      change HP of the Player to HP of the Player * WIMPT;
      change HP of the Player to HP of the Player / WIMPB;

Wimping is an action applying to nothing. Understand "Wimp" or "Whimp" as wimping.

Carry out Wimping:
   if CourVariable is 1 begin;
      say "You have locked this game in COURAGE mode, preventing access to that command." instead;
      end if;
   if WimpVar is 2 begin;
      say "You are already in WIMP combat-difficulty mode." instead;
      end if;
   Change WimpVar to 2; Change WIMPT to 8; Change WIMPB to 3; [--- near limit see below]
   Say "Battle difficulty switched to WIMP mode (barbarian Hit Points boosted, verily)!";
      change HP of the Player to HP of the Player * WIMPT;
      change HP of the Player to HP of the Player / WIMPB;

[Note that if the WIMPT variable goes too high; the game could crash (especially in WIMP mode), so keep those fractions as simple as you can, and always test your best armor combo in WIMP]

Volume of DOCUMENTED SECONDARY ACTIONS

Book of the WAIT Command

Understand "Rest" and "Repose" as waiting.

Book of the INVENTORY Command

Understand "TABULATE" or "TAB" or "T" as taking inventory.

Instead of taking inventory: Say "[if the number of things enclosed by the player is 0]You carry only your trusty THESKIAN DUFFEL BAG.[end if][if the number of things enclosed by the player is 1]You carry only [SCHTUFF], and your trusty THESKIAN DUFFEL BAG.[end if][if the number of things enclosed by the player is greater than 1]You bear the following (both on your person and stashed in your trusty THESKIAN DUFFEL BAG): [SCHTUFF].[end if]"

To say SCHTUFF:
   list the contents of the player, as a sentence.

Chapter of the THESKIAN DUFFEL BAG

The THESKIAN DUFFEL BAG is a backdrop. It is everywhere. Understand "sack/trusty/canvas/duffle" as the THESKIAN DUFFEL BAG. The description of the THESKIAN DUFFEL BAG is "The DUFFEL BAG is crafted of sturdy THESKIAN CANVAS. It bears the stains, smells, and wear of many years of broody, restless barbarian travel."

Before taking inventory when the number of things enclosed by the player is 0: have the parser notice the THESKIAN DUFFEL BAG.

Before doing anything except examining or attacking or dropping or taking [or conversing with] to the THESKIAN DUFFEL BAG, say "The THESKIAN DUFFEL BAG is practically an extension of you; you've carried it since you were an infant, and it does its job without commands." instead;

Before dropping the THESKIAN DUFFEL BAG, say "You've carried the THESKIAN DUFFEL BAG since you were an infant! It is integral to your life, your well-being, and your smell." instead;

Before taking the THESKIAN DUFFEL BAG, say "It is here by your side, as always." instead;

Before attacking the THESKIAN DUFFEL BAG, say "During many points in your life, the THESKIAN DUFFEL BAG has been your only friend, confidante, and bed-partner. Save your mindless rages for your foes, barbarian. Don't hurt the ones you love." instead;

Volume of Hacks and Fiddles

Chapter of Ranks

Table of Rankings	
Score	Rank
0	"[Grade]"
500	"SOMEONE SHOULD REALLY PUT THE ULTIMATE RANK RIGHT HERE"

[--- The Two kinds of Random Ranks are RankDOWN (bad) and RankUP (good) ---]

To say Grade:
   Let CoinToss be a random number between 75 and 325; [Such an impressive coin!]
   If CoinToss > Score, say "[RankDOWN]";
   If CoinToss is Score, say "[RankUP], which isn't too bad";
   If CoinToss < Score, say "[RankUP]";

To say RankDOWN:
   Let CoinToss be a random number between 1 and 2;
   If CoinToss is 1, say "'[RandomRank]'";
   If CoinToss is 2, say "'[RankRandom]'";

To say RankUP:
   Let CoinToss be a random number between 1 and 2;
   If CoinToss is 1, say "'[RandomRankUP]'";
   If CoinToss is 2, say "'[RankRandomUP]'";

To say RandomRank:
   say "[Footloose] [Duder]".

To say RankRandom:
   say "[Duder][Dunroamin]".

To say RandomRankUP:
   say "[FootUP] [DudeUP]".

To say RankRandomUP:
   say "[DudeUP][DunUP]".

To Say Footloose: show the next response from the Table of Footloose.
To Say Duder: show the next response from the Table of Duder.
To Say Dunroamin: show the next response from the Table of Dunroamin.
To Say FootUP: show the next response from the Table of FootUP.
To Say DudeUP: show the next response from the Table of DudeUP.
To Say DunUp: show the next response from the Table of DunUp.

Section of Rank-Segment Tables

Table of Footloose
response
"Cut-Rate"
"Degenerate"
"Tumbledown"
"Wilden"
"Would-Be"

Table of Duder
response
"Brute"
"Foxherd"
"Hooligan"
"Lout"
"Yokel"

Table of Dunroamin
response
" in Distress"
" with Two Left Feet"
", Lost in the Wilderness"
", Third Class"
"-in-Training"

Table of FootUP
response
"Big Manly"
"Glorious"
"Master"
"Stout-Hearted"
"Valorous"

Table of DudeUP
response
"Death Dealer"
"Myrmidon"
"Paragon"
"Slaughterhouse"
"Warrior"

Table of DunUP
response
" Admired By All"
" Destined For Glory"
" Nonpareil"
" of Science"
" Supreme"

Book of the Status Bar

To say PL: say " [if HP of Player < 10] [end if][if HP of Player < 100] [end if][if HP of Player < 1000] [end if][if MaxHP of Player < 10] [end if][if MaxHP of Player < 100] [end if][if MaxHP of Player < 1000] [end if]".
To say PQ: say "   [if Score < 10] [end if][if Score < 100] [end if]".

Table of EmergencyStatusBar
left	central	right
" [Location]"	""	""
" [Exit List]"	""	""

Table of StatusBar
left	central	right
" [Location]"	""	"[PL]HIT POINTS: [if HP of Player < MaxHP of Player and indicate-unvisited is show-unvisited][unvisited-mark][end if][HP of Player][if HP of Player < MaxHP of Player and indicate-unvisited is show-unvisited][end-unvisited-mark][end if]/[MaxHP of Player]"
" [Exit List]"	""	"[PQ]QUEST RATE: [Score]/[Maximum Score]"

Table of BattleBar
left	central	right
""	"  BARBARIAN HIT POINTS: [HP of the Player]/[MaxHP of the Player]"	""
""	" [FoeFum] HIT POINTS: [HP of FoeFum]/[MaxHP of FoeFum]"	""

Rule for constructing the status line when RegularBar is 0:
      fill status bar with Table of BattleBar;
   rule succeeds.

Rule for constructing the status line while the screen width is less than 45:
   fill status bar with Table of EmergencyStatusBar;
   rule succeeds.

Rule for constructing the status line when RegularBar is 1:
   fill status bar with Table of StatusBar;
   rule succeeds.

Rule for printing the name of a direction (called the way) while the screen width is less than 55: choose row with a heading of the way in the Table of DirAbbreviationTiny; say "[shortcut entry]".

Rule for printing the name of a direction (called the way): choose row with a heading of the way in the Table of DirAbbreviation; say "[shortcut entry]". 

Table of DirAbbreviation 
heading	shortcut    
north	"North"    
northeast	"Northeast"    
northwest	"Northwest"    
east	"East"    
southeast	"Southeast"    
south	"South"    
southwest	"Southwest"    
west	"West"    
up	"Up"    
down	"Down"    
inside	"In"    
outside	"Out"

Table of DirAbbreviationTiny 
heading	shortcut    
north	"N"    
northeast	"NE"    
northwest	"NW"    
east	"E"    
southeast	"SE"    
south	"S"    
southwest	"SW"    
west	"W"    
up	"Up"    
down	"Dn"    
inside	"In"    
outside	"Out"

Include Exit Lister by Eric Eve. Understand "color" or "colour" as exit colouring.

Chapter of the Delayed Something New and Unwanted Entries

Understand the command "consult" as something new.
Understand the command "answer" as something new.
Understand the command "exits" as something new.
Understand the command "exits on" as something new.
Understand the command "exits off" as something new.

Book of Disabling Notify

To quietly turn off score notification:
   (- notify_mode = 0; -).
When play begins:
   quietly turn off score notification;

Book of namegoing (Adapted from Examples)

Understand "[any room]" as namegoing. Understand "go to/into/inside/aboard [any room]" or "go [any room]" or "enter [any room]" or "go to [any room]" or "use [any room]" or "visit [any room]" as namegoing. namegoing is an action applying to one thing.

Check namegoing:
   if the noun is the location, say "[The location] is thy current environment, barbarian. Didst thou mean something other?" instead;
   if the noun is not adjacent, say "The way there is nowhere near, barbarian." instead;

Carry out namegoing:
   let aim be the best route from the location to the noun, using doors;
   if aim is not a direction, say "[generic-error]" instead;
   try going aim;

Book of Examining Nearby Places

Understand "examine [any room]" or "look at [any room]" or "regard [any room]" or "REG [any room]" or "R [any room]" as placelooking. Placelooking is an action applying to one thing.

Check placelooking:
   if the noun is the location, try looking instead;
   if the noun is adjacent, say "A quick visit to [the noun] wouldst satisfy thy curiosity." instead;
   if the noun is not adjacent, say "You are are nowhere near [the noun], barbarian." instead;

Book of ALL

Rule for deciding whether all includes people: it does not.
Rule for deciding whether all includes things enclosed by the player when taking: it does not.
Rule for deciding whether all includes things enclosed by people: it does not.
Rule for deciding whether all includes things enclosed by the player when dropping: it does.
Rule for deciding whether all includes scenery: it does not.
Rule for deciding whether all includes things which are fixed in place: it does not.
Rule for printing room description details: stop.

Volume of What Are Normally Cumberland House Rules

Book of General Fiddles

Use memory economy.
Use American dialect.

Understand "him" as a man.
Understand "her" as a woman.
Understand "woman" as a woman.
Understand "wench" as a woman.
Understand "girl" as a woman.
Understand "maid" as a woman.
Understand "lass" as a woman.
Understand "man" as a man.
Understand "person" as a person.

Before looking: say " "

Book of Shorter Formatting Codes

To say i  -- beginning say_XX -- running on: (- style underline; -).
To say b -- beginning say_XX -- running on: (- style bold; -).
To say f -- beginning say_XX -- running on: (- style fixed; -).
To say n -- ending say_XX -- running on: (- style roman; -).

[Courtesy of the Recipe Book with my own modifications, this allows semi-HTML-like markup for bold type [bold type] italic type [italic type] and fixed letter spacing [fixed letter spacing] type, any application of which must be ended with a Roman type [roman type] tag. This markup option complements and does not replace the usual method of using [bold type]and[roman type] brackets, etc.]

Book of Reference Actions Out of World

TrnCounting is an action out of world. Understand "Turn" or "Turns" as TrnCounting. Carry out TrnCounting: Say "This is turn [turn count].".

Book of Default Messages Fiddled-With

Include Default Messages by David Fisher.

Table of custom library messages (continued)
Message Id	Message Text
LibMsg <report player taking>			"Seized.[line break]"
LibMsg <report player dropping>				"Discarded.[line break]"
LibMsg <cannot exit when not within anything>		"[generic-error]"
LibMsg <person ignores command>	"[generic-error]"
LibMsg <cannot talk to absent person>	"[generic-error]"
LibMsg <cannot enter something carried>	"You are a strange one, barbarian.[line break]"
LibMsg <cannot enter something not enterable>	"[The noun] seemeth [one of]less than[or]hardly[or]less than[or]somewhat less than[at random] comfy.[line break]"
LibMsg <cannot exceed carrying capacity>	"Thou art already carrying much, barbarian.[line break]"
LibMsg <cannot reach within other places>	"Curious notion.[line break]"
LibMsg <cannot take other people>		"[The main object] seems comfy right here.[line break]"
LibMsg <cannot take scenery>	"Curious notion.[line break]"
LibMsg <cannot take something fixed>	"Thinkest again.[line break]"
LibMsg <command cut short>	"(some actions were not completed)[line break]"
LibMsg <unimportant object>	"Nothing you need to worry about.[line break]"
LibMsg <report player waiting>	"[waitline].[line break]"
LibMsg <unknown object>	"I don't see what you're referring to.[line break]"
LibMsg <block vaguely going>				"But in what direction, barbarian?[line break]"

To say waitline:
   say "[if the FoeFum is visible and the HP of the player < MaxHP of the player]You pause in manly contemplation, displaying your contempt for [the FoeFum][end if][if a Foe which is not the FoeFum is visible and the HP of the player < MaxHP of the player]You pause in manly contemplation, but with [the random touchable foe] nearby, you cannot REST well enough to heal[end if][if no Foe is touchable and the HP of the player < MaxHP of the player]You stop to rest for a moment[end if][if the HP of the player is the MaxHP of the player]You pause in manly contemplation[end if]";

Volume of the BARBARIAN

Understand "barbarian/fist/thews" as yourself.

Check examining the player:
   say "You have the savage bearing of an upland tribesman, quick like a THESKIAN MOUNTAIN CAT and cruel of eye, though [']tis truth that your heart is not unkind. Your mirth is as mighty as your gloom, and your ire as potent as your warmer passions." instead;

Before Attacking the player:
   say "[line break]Oh? Such a lament for us all, and such an un-deserved victory for thy foes. But [']tis your own life to live, or to take ... and so, by your own hand:";
      change the HP of the Player to -9999 instead;

Check Conversing with the player:
   say "You've tried it before. You never get any of the jokes." instead;

Check Taking the player:
   say "Phrased in that way, it soundest naughty." instead;

Check Using the player:
   say "Not right now. Anyone might walk by and see!" instead;

The player has a number called Skill. The Skill of the player is 80.
The player has a number called Bonus. The Bonus of the player is 1.
The player has a number called Healing Rate. The Healing Rate of the player is 1.
The player has a number called HP. The HP of the player is 15.
The player has a number called MaxHP. The MaxHP of the player is 15.
The carrying capacity of the player is 100.

Chapter of the Barbarian's Every Living Game Turn

HPDIV is a number variable. HPDIV is 0.
SCDIV is a number variable. SCDIV is 0.
BODIV is a number variable. BODIV is 0.
DRBASE is a number variable. DRBASE is 0.
DRMID is a number variable. DRMID is 0.
DR is a number variable. DR is 0.
LOADPENALTY is a number variable. LOADPENALTY is 0.
ENCTHRESH is a number variable. ENCTHRESH is 5.
NODEATH is a number variable. NODEATH is 0. [change to 1 temporarily for things like the Gladiator fights, where the Barbarian can be defeated but not actually killed]

Every turn: [Damage Bonus and WIMP Damage Adjustments]
   change BODIV to score divided by 35;
   change Bonus of the player to BODIV + 1;
   change Bonus of the Player to Bonus of the Player * WIMPT;
   change Bonus of the Player to Bonus of the Player / WIMPB; 

Every turn: [Wimping the Weapon Damage]
   if the player encloses a wielded weapon begin;
      change PCLO to LoDam of the ReadyWeapon * WIMPT;
         change PCLO to PCLO / WIMPB; 
      change PCHI to HiDam of the ReadyWeapon * WIMPT;
         change PCHI to PCHI / WIMPB;
   end if;

Every turn: [Attack Skill]
   change SCDIV to score divided by 25;
   change Skill of the player to SCDIV + 80;

Every turn: [Attack Skill Modifiers]
   change LOADPENALTY to 0; [--- Encumbrance]
   if the number of things enclosed by the player is greater than ENCTHRESH begin;
      let BLOAT be the number of things enclosed by the player minus ENCTHRESH;
      let OVERLOAD be BLOAT divided by 2;
      change LOADPENALTY to OVERLOAD multiplied by OVERLOAD;
      change the Skill of the player to the Skill of the player minus LOADPENALTY;
   end if;
   if the Skill of the Player < 10, change the Skill of the Player to 10;

Every turn: [Maximum Hit Points]
   change HPDIV to score divided by 5;
   change MaxHP of the player to HPDIV + 15;
   change MaxHP of the Player to MaxHP of the Player * WIMPT;
   change MaxHP of the Player to MaxHP of the Player / WIMPB;

Every turn: [Check for Lost Armor, Weapons, and Limbs]
   if the player does not enclose a girded suit begin;
      now the ReadyArmor is the DefaultArmor;
      now all suits are ungirded;
      now DRT is 0;
      now DRB is 100;
   end if;
   if the player does not enclose a wielded weapon begin;
      now the ReadyWeapon is the DefaultWeapon;
      now all weapons are unwielded;
      now PCLO is 1;
      now PCHI is 6;
   end if;

Every turn: [Benefits of Armor and the AMULET of SCIENCE]
   change DRBASE to the MaxHP of the player;
   change DRMID to DRBASE multiplied by DRT;
   change DR to DRMID divided by DRB;
   increase the MaxHP of the player by DR;
   if the MaxHP of the player is greater than 9999 begin;
      change MaxHP of the player to 9999;
   end if;

Every turn: [Determine Healing Rate]
   change the Healing Rate of the player to the MaxHP of the player divided by 6;
  [ if the Healing Rate of the player is less than 1 begin;
      change Healing Rate of the player to 1;
   end if; ]

Every turn: [Healing For Real, Adjusting to Ceiling]
   if no foe is touchable begin;
      change RegularBar to 1;
      Increase the HP of the player by the Healing Rate of the player;
   end if;
   If the HP of the player is greater than the MaxHP of the player begin; [Ceiling]
      change the HP of the player to the MaxHP of the player;
   end if;

Every turn: [The GRIM FUCKING REAPER]
   if the HP of the player is less than 1 begin;
      change HP of the player to 0;
   end if;
   if the HP of the player < 1 and NoDeath is 0 begin;
      end the game saying "YOU ARE NO MORE";
  end if;

Volume of the Game World

Book of the MEADOW

The MEADOW is a room. "You are in a meadow. There is a BUILDING here that you may ENTER, if you like. Or, you could just stand here in the meadow, typing OATH and REPOSE a lot and perhaps using the PROWESS command to see how badass you are." The player is in the MEADOW. Understand "field" as the meadow.

The GREAT FLAIL is here. The GREAT FLAIL is a weapon with LoDam 2, HiDam 9.

[Note the lack of any kind of bellcurve in the weapon damage. I bet Hank had no idea what the prof was up to with stuff like that.]

The NOTICE is here. The description is "This scrap of parchment explains that this 'game' is no game at all, really (though you can play it to get the feel of things). Really, it's just a compiled example of the stripped-down code released for those interested in making free homebrew sequels, prequels, or companion games to [b]TREASURES OF A SLAVER[']S KINGDOM[n].[paragraph break]The scrap also summarizes some of the instructions contained within the source code, and includes some [i]excellent[n] advice for using it ... but just as you start reading that part, an unexpected supernatural wind whips the parchment out of your hand, and it is lost forever. If only you had a GOLD CREDIT for every time [i]that[n] happened ...[whipaway]"

To say whipaway:
   remove the notice from play.

Book of the BUILDING

The BUILDING is inside from the MEADOW. "You are inside a building. You could EXIT from here to go back outside, or you could venture UP into the gloomy-looking ATTIC." Understand "house" as the building.

The SUIT OF BARGAIN CHAINMAIL ARMOR is here. It is a suit with DRTop 2, DRBottom 3. The description is "You hath seen SPACEFARERS from GOD CITY drinking their fizzy and sweet elixirs from [']POP-TOP['] CANS. What thou hast not seen until now is a suit of CHAINMAIL forged from the pop-tops they discard." Understand "chain/mail" or "chain mail" as the suit of CHAINMAIL armor. 

Book of the ATTIC

The ATTIC is up from the BUILDING. "You are in the ATTIC of the BUILDING, which seems to have been converted into a showroom where all the dust in VANTH could be stored. It[']s difficult to breathe."

Chapter of the Boogeyman

A BOOGEYMAN is a foe with HP 19, MaxHP 19, MinWhup 1, MaxWhup 20, FoeSkill 67. The BOOGEYMAN is in the ATTIC. "In the dusty corner there lurketh a BOOGEYMAN!" The description of the BOOGEYMAN is "[']Tis much like a man, but boogeyer.". The Miss-Declare of the BOOGEYMAN is "The BOOGEYMAN strikes - but he misses!". The Attack-Declare of the BOOGEYMAN is "[BOOGEYMANAttack]". To say BOOGEYMANAttack: show the next response from the Table of BOOGEYMAN Attack. The ByeNow of the BOOGEYMAN is "The BOOGEYMAN collapses into the DUST of this thrice-accursed ATTIC, and will move no more.[deadprop]". Understand "boogey" as the BOOGEYMAN.

Table of Table Types (continued)		
tabname	index	tabtype
Table of BOOGEYMAN Attack	0	shuffled-list

Table of BOOGEYMAN Attack
response
"The BOOGEYMAN attacks!"
"The BOOGEYMAN whumps you with the power of BOOGEY!"
"With a HEARTY LAUGH, the BOOGEYMAN thumpest thou!"

Check Conversing with the BOOGEYMAN:
   say "The BOOGEYMAN just stares at you and [one of]growls[or]snickers[or]spits on the floor[in random order]." instead;

Before Taking the BOOGEYMAN:
   say "The BOOGEYMAN leaps away as you try." instead;

Check Using the BOOGEYMAN:
   say "Unless thou dost intend something kinky (and extremely dangerous), you can fathom no immediate use for [the noun]." instead;

Before going when the BOOGEYMAN is touchable:
      say "The BOOGEYMAN moves to block your exit." instead;

Section of the Boogeyman Sick of Waiting

AngryBoogey is a scene. AngryBoogey begins when the Boogeyman is touchable for the fourth turn and the FoeFum is not the Boogeyman. AngryBoogey ends when AngryBoogey begins.

When AngryBoogey begins:
   Say "The BOOGEYMAN suddenly snarls, and flexes his muscles as if preparing to strike! Your keen barbarian senses detect hostility.";
   Now the FoeFum is the Boogeyman;

Section of the Victory

The deadman is a thing. The printed name of the deadman is "REALLY WELL AND TRULY DEAD BOOGEYMAN".

To say deadprop: move the deadman to the attic;

Victory is a scene. Victory begins when the HP of the Boogeyman is 0. Victory ends when Victory begins.

When Victory begins:
   end the game saying "VICTORY IS THINE".

Book of Regions

The Outdoors is region. [---] The MEADOW is in the Outdoors.  [---]

The Indoors is a region. [---] The BUILDING is in the indoors. [---] The Innies is a region. The Innies is in the Indoors. [---] The ATTIC is in the Innies. [---]

Chapter of Innies Rules

Before going inside when the player is in the innies, say "You're already here, barbarian." instead.

Before going nowhere when the player is in the Innies, try exiting instead.

Chapter of Room Categories

A Room can be SFX. [An SFX room is one free from random atmospherics]

Chapter of Backdrops

The GROUND is a backdrop. It is everywhere. It is unenterable. The description of the GROUND is "[If the player is in the Outdoors]As a wild Warrior-born, it pleases you to stride upon the open ground in the fresh air, instead of on some cold FLOOR indoors.[end if][if the player is in the Indoors]You feel suffocated just considering it ... you long for the outdoors, where a Warrior-born can run free and naked on the wild soil, unfettered by walls and ceilings, with his THESKIAN DUFFEL BAG fluttering in the fresh breezes.[end if]". Understand "dirt/sand/mud/earth/muck/mire/murk" or "grass/grasses/flower/flowers" or "muck/mire" or "path/paths/road/highway/track/trail" or "land/deck" as the GROUND when the player is in the outdoors. The indefinite article of the GROUND is "the". Rule for printing the name of the GROUND when the player is in the indoors: say "WALLS, FLOOR and CEILING". Understand "wall/walls/floor/deck/ceiling/bulkhead/bulkheads" as the GROUND when the player is in the Indoors.

The SKY is a backdrop. It is unattainable. It is in the outdoors. The description is "The sky is tinged orange and red by the setting sun, struggling to send the bloody rays of evening through heavy clouds. It is a sky rich with the anger of the slaves, a sky that cries out for VENGEANCE! Or, mayhap, [']tis only you." Understand "cloud/clouds/rain/drizzle/sun/blood-red/sunset" and "blood-red sun" and "blood red sun" as the SKY. The indefinite article of the SKY is "the".

The AIR is a backdrop. The air is everywhere. It is unenterable. The description is "The AIR smellest better, now that thee are here.". Understand "scents/smells/odors/stink/stench/scent/smell/odor/aroma/breeze/breezes/wind" as the AIR. The indefinite article of the AIR is "the".

[... and some ToaSK samples of general backdrops ...]

[Some ROCKS are a backdrop. Some ROCKS are in the SEASHORE, the ROCKY RUIN, the LONELY HILL, the ABANDONED QUARRY, the GRAVEL PIT OF ROGUES, the SNOWY MOUNTAINSIDE, THE FROSTED UPLANDS, THE WINDING TRAIL, THE PEAK OF MOUNT GELIDUS, THE DIZZYING CLIFFSIDE, THE CAVE, THE GLOWING CAVERN, THE SLAVE PENS, THE OLD STONE BRIDGE, and THE MOUNTAIN STREAM. Understand "rock/gravel/stone/stones/crags/cliff/cliffside" or "crags of ancient rock" or "ancient rock" as some rocks.

Some ICING is a backdrop. Rule for printing the name of some ICING: say "ICE & SNOW". Understand "snowbank/snowbanks/bank/banks/frost/snow/ice/dustings/winter" or "dustings of winter" or "ice & snow" as some ICING. Some ICING is in the SNOWY MOUNTAINSIDE, FROSTED UPLANDS, MOUNTAIN STREAM, WOODED FOOTHILLS, WINDING TRAIL and the PEAK OF MOUNT GELIDUS. The description is "It seemeth quite frosty."

A VIEW OF THE MOUNTAINS is a backdrop. It is in the outdoors. It is unattainable. The description is "The BLEAK MOUNTAINS define the eastermost extent of the SLAVER KING'S domain. The highest is the craggy peak of MOUNT GELIDUS." Understand "mountain/peaks/bleak/hills" or "bleak mountains" as a view of the mountains. Before doing anything to the VIEW OF THE MOUNTAINS when the location of the player is the PEAK OF MOUNT GELIDUS, say "You're standing at the very peak of MOUNT GELIDUS." instead.

The VIEW OF MOUNT GELIDUS is a backdrop. It is unattainable. It is in the outdoors. The description is "The great MOUNT GELIDUS is currently capped with snow." Understand "peak/summit" as the view of mount gelidus. Before doing anything to the VIEW OF MOUNT GELIDUS when the location of the player is the PEAK OF MOUNT GELIDUS, say "You're standing on it." instead.]

Chapter of Trivial Backdrop

Some TRIVIA are a backdrop. TRIVIA are everywhere. Trivia are ambiguously plural. The printed name is "BACKGROUND NONSENSE". Before doing anything to TRIVIA, say "Such distractions can wait [']til thy QUEST is done." instead. Understand "dust" as TRIVIA.

Does the player mean doing anything to some TRIVIA: it is very unlikely.

Chapter of Atmospherics Rules

ATMOV is a number variable. ATMOV is -12. [-12]
   ["Atmo Variable" determines delay at the beginning of the game before random atmo kicks in]
ATMOF is a number variable. ATMOF is 50. [50]
   ["Atmo Frequency" ... when ATMOV is positive odds of atmo incident are (ATMOV / ATMOF)]
ATMOB is a number variable. ATMOB is -8. [-8]
   ["Atmo Buffer" between atmo incidents, since ATMOV has to crawl back to positives]

To say atmokill: [-- insert [atmokill] into a string to delay atmosphere from showing up near it]
  change ATMOV to ATMOB; 

Before waiting:
   if HP of Player is MaxHP of Player begin;
     increase ATMOV by a random number between 0 and 2; [--- passive increase is double normal, on average, provided the player isn't busy healing]
   end if;

Every turn:
   if the location of the player is visited begin;
      if no Foe is touchable begin;
         increase ATMOV by 1;
          if a random chance of ATMOV in ATMOF succeeds begin;
            say "[LocalColor][run paragraph on]";
            change ATMOV to ATMOB;
         end if;
      end if;
   end if;

To say LocalColor:
   if the location of the player is in the OUTDOORS and the location of the player is not SFX begin;
      let CoinToss be a random number between 1 and 100;
         if CoinToss > 75 begin;
            say "[AnyAtmo]"; [Gunwar's chattering was added like this: "[if Gunwar is touchable][one of][Gunwarchatter][or][AnyAtmo][purely at random][otherwise][AnyAtmo][end if][paragraph break]"]
            end if;
         if CoinToss < 76 begin;
            say "[OutdoorAtmo]";
            end if;
   end if;
   if the location of the player is in the INDOORS and the location of the player is not SFX begin;
      let CoinToss be a random number between 1 and 100;
         if CoinToss > 70 begin;
            say "[AnyAtmo]";
            end if;
         if CoinToss < 71 begin;
            say "[IndoorAtmo]";
            end if;
   end if;
   [--- End of Generic Atmospherics; below are Room-Specific ones for "SFX" Rooms]
[   if the location of the player is the CHAMBER OF FOON begin;
      say "[FoonAtmo][paragraph break]";
      end if;]

To say IndoorAtmo: show the next response from the Table of Indoor Atmospherics.
To say OutdoorAtmo: show the next response from the Table of Outdoor Atmospherics.
To say AnyAtmo: show the next response from the Table of Anywhere Atmospherics.

Volume of Additional Scenes

PursuitVar is a number variable. PursuitVar is 0. [<-- Marks the times when a foe pursues the PC]

Volume of EVOCATIVE FAILURES

[in which we add as many USE/USE WITH responses as we can think of and will fit, safely at the end of all things so that any other responses take precedence]

Book of USING Failures

Check using:
   if the noun is the NOTICE, say "You fan yourself briefly with the NOTICE. Ahh." instead;

Book of USING WITH Failures

Check using it with: [specific combinations]
   if the noun is the NOTICE and the second noun is the GREAT FLAIL, say "You try wrapping the NOTICE around the handle of the GREAT FLAIL, but this improveth not the grip." instead;
   if the noun is the GREAT FLAIL and the second noun is the NOTICE, say "You wail away at the notice for a while, venting years of frustration at your own limited literacy." instead;
   if the noun is the NOTICE and the second noun is the BOOGEYMAN, say "The boogeyman scowls as he REGARDS the notice. Then he takes it from you, eats it, and belches. What a stink![whipaway]" instead;

[Check using it with: [special-case priorities] [ToaSK had a few like this:]
   if the second noun is the SOLID GOLD STATUE, say "The SOLID GOLD STATUE taketh no heed, for she art only a dead thing of metal ... warmly-hued, but cold to the touch." instead;]

Check using it with: [combinations - less specific]
   if the noun is a weapon and the second noun is a suit, say "[']Tis better practice, barbarian, to direct thy weapon against a suit of armor with a FOE inside." instead;

Check using it with: [second nouns - specific first, kinds after]
   if the second noun is a BOOGEYMAN, say "The BOOGEYMAN glares at you like you're an idiot." instead;
   if the second noun is the NOTICE, say "Your attempt to create an ORIGAMI MODEL based on [the noun] comes to naught." instead;

Check using it with: [nouns - specific first, kinds after]
   if the noun is the CHAINMAIL, say "You scrape the discarded pop-tops against [the second noun], exactly like GRONDARK THE VILLAGE IDIOT used to do back home. You stare into space for a moment ... you never really told GRONDARK how much you admired him and depended on his teachings." instead;
   if the noun is a weapon, say "Thou art really only accustomed to ASSAILING things with a [noun], preferably in a frothing, bloody rage filled with lusty war-oaths, suggestive hip-thrusts and savage leering. Just thinking about it arouseth thee." instead;

Check using it with: [special bottom-priority]
   if the second noun is a person, say "[The second noun] taketh no interest in [the noun]." instead;
   if the second noun is scenery, say "[ComboFailure]." instead;

Volume of Help and Information

Book of the ABOUT Command

Abouting is an action out of world. Understand "About" or "Credits" or "Author" as Abouting.

Carry out Abouting: say "[AboutStuff]".

To say AboutStuff:
   say line break;
   say "Here's a bit about this game and the designer of it. I really should write something here.";
   say line break;
   say "Portions of this game appeared originally in [b]Treasures of a Slaver[']s Kingdom[n], copyright (c) 2007,2008 by S. John Ross, and appear here by permission. [quotation mark]Encounter Critical[quotation mark] and terms unique to it are trademarks of S. John Ross.";

Book of HELP

CommandRequesting is an action out of world. Understand "Commands" or "Help" or "Hint" or "Instructions" or "Action Commands" as CommandRequesting. Carry out CommandRequesting:
   say line break;
   say "Five [quotation mark]action commands[quotation mark] are the heart of the barbarian[']s experience: [bold type]REGARD[roman type] (examine, consider), [bold type]SEIZE[roman type] (take into your possession), [bold type]USE[roman type] (make use of in some way), [bold type]PARLEY[roman type] (converse with peaceably), and [bold type]ASSAIL[roman type] (do violence upon). These are verbs to be followed by a noun: PARLEY WITH ALICE; SEIZE THE IDOL; USE THE BANANA. For greater complexity, the [bold type]USE[roman type] command can combine two nouns: USE THE BRIBE WITH THE MAGISTRATE, USE THE DAGGER ON THE ROPE. [italic type]All success depends on these action commands.[roman type]";
   say line break; say line break;
   say "Type a direction (NORTH, SOUTH, EAST, WEST, UP, DOWN, IN, OUT, EXIT, ENTER) to travel. The proper command is [bold type]JOURNEY[roman type], but direction alone will suffice. Other useful commands include: PILLAGE (seize everything at once), DISCARD (drop a thing), SHED (drop many things at once), and REPOSE (pause to heal or think great thoughts).";
   say line break;
   say "Some important commands are for the player rather than the barbarian. These include SAVE and RESTORE to preserve and return to game-states between sessions, QUIT to abandon play, and reference commands such as TABULATE, PROWESS, and SCORE. Combat difficulty may be adjusted with the OFFICIAL, APPRENTICE and WIMP commands. Other commands (and shortcuts) are also provided. Refer to your game manual.";

Volume of Support Tables

Book of Randomizing Tables

Table of Table Types (continued)		
tabname	index	tabtype
Table of Anywhere Atmospherics	0	shuffled-list
Table of Barbarian Bloopers	0	shuffled-list
Table of Barbarian Mayhem	0	shuffled-list
Table of Combo Mockery	0	shuffled-list
Table of Duder	0	shuffled-list
Table of DudeUP	0	shuffled-list
Table of Dunroamin	0	shuffled-list
Table of DunUP	0	shuffled-list
Table of Footloose	0	shuffled-list
Table of FootUP	0	shuffled-list
Table of Generic Errors	0	shuffled-list
Table of Huronian Portions	0	shuffled-list
Table of Indoor Atmospherics	0	shuffled-list
Table of Outdoor Atmospherics	0	shuffled-list
Table of Utilized Mockery	0	shuffled-list

Book of Atmospheric Tables

Table of Indoor Atmospherics
response
"A tiny insect skitters across the floor, then skitters away again."
"Some dust maketh you sneeze."
"There is a mournful whistling in the walls, as if a great wind is gusting outside."
"There is a scratching noise from inside the walls."
"You squint to look around; this place is poorly lit."

Table of Outdoor Atmospherics
response
"A cold drizzle blows in."
"A gentle breeze picks up."
"A twig snaps nearby."
"You feel the wind change direction."
"You hear a gentle cracking noise somewhere nearby, like rocks tumbling onto one another."

Table of Anywhere Atmospherics
response
"Something scurries over your foot."
"There is a chittering of insects nearby."
"You craveth ale."
"You feel a bit tired."
"You feel a prickling at the back of your neck."

Book of Score Tables

Chapter of Object & Enemy Scoring

[---]

Check taking:
   if the noun is an item listed in the Table of Object Values begin;
      award score entry points;
      blank out the whole row;
   end if;

Check looking:
   if the location is an item listed in the Table of Object Values begin;
      award score entry points;
      blank out the whole row;
   end if;

[---]

Table of Object Values	
Item	Score
GREAT FLAIL	1 [remove and replace with genuine rows of places and objects, with their value]
Suit of Chainmail Armor	1
Building	1
Attic	1
Boogeyman	495


[That's all! Drop me a line at sjohn@io.com - I like hearing from folks!]
[www.cumberlandgames.com]





